VBScriptまめちしきー。UNIXサーヴァをうろちょろしていると，改行コードなしに全レコードがずらずら繋がってひと塊になっている固定長のテキストファイルなんてモノにぶつかる。目眩がするわ。Windows
PCでこんなの開いても検証できないよ。
まづはテキストエディタの右端折り返しで調整してみる。まぁ，すぐ厭になりますナ。しょーがないんで一定間隔で改行コードを挿入するスクリプトを書く。Rubyなんか入ってないからVBScriptですナ。何はともあれReadAllしてファイルの頭からLen|LenBでレコード長ぶん計ってはちぎってWriteLineしてみよう。と，漢字項目が交じってたりして切れ目が狂ってきますナ。しょーがないんで１文字づつ全半角チェックして２足したり１足したりする関数を作って噛ませますナ。
それでしばらくは用が足せてたんだけど，あっ何と言うことだ，憎たらしいことにLOW-VALUEがデータとして入りこんでるファイルが登場したではないかいな。こういうのをReadAllすると，LOW-VALUEの所から後ろが予測不可能な展開を見せ，早い話が読みこんだとき既に壊れている。むきーっ。
ここでLOW-VALUEって何？と言う大きなお友だちは，窓際に居る大きな大きなお友だちに訊いてみましょうネ。
しょーがないんでテキストで処理するのを諦め，バイナリとして扱ってみる。
Set objADR = CreateObject("ADODB.Stream")
Set objADW = CreateObject("ADODB.Stream")
objADR.Type = 1 'バイナリ読み
objADR.Open
objADR.LoadFromFile (inpF)
objADR.Position = 0
objADW.Type = 1 'バイナリ書き
objADW.Open
Do Until objADR.EOS = True
s = objADR.Read(recLen) '既知のレコード長ぶん読みこむ
objADW.Write s '読みこんだのをバッファに書く
objADW.Write vbCrLf '改行コードをバッファに書く
Loop
objADW.SaveToFile (outF) 'バッファからファイルに出力
あー，このほうが純粋にバイト長で切りとれるから全半角問題も片づいてイイかも。と思ったら好事魔多し，上のコーディングでは改行コードのつもりで vbCrLf
を書きだした所でエラーになるのである。Chr(10)やChr(13)・asc(10)・&H10 いづれも不可である。とにかくテキストコードを書こうとすると，タイプがちなうみたいなコトを言って動いてくれない。敗北感まる囓りだっ。
あーそうかよ，バイナリならいーんだなバイナリなら。と，改行コード専用の ADODBオブジェクト（紛らわしいが３文字目は「オー」ざますよ）を生成してやったら……，
Dim objFS
Dim objADR, objADW, objADLF
Dim inpF, outF
Dim recLen
Dim binLF, s
inpF = "a.dat"
outF = "a_LF.dat"
recLen = 128 'レコード長
Set objFS = CreateObject("Scripting.FileSystemObject")
Set objADR = CreateObject("ADODB.Stream")
Set objADW = CreateObject("ADODB.Stream")
Set objADLF = CreateObject("ADODB.Stream")
If objFS.FileExists(outFile) Then
'出力ファイルが既存なら消しとかないとうまくない。
objFS.DeleteFile outFile, True
End If
objADR.Type = 1 'バイナリ読み
objADR.Open
objADR.LoadFromFile (inpF)
objADR.Position = 0
objADW.Type = 1 'バイナリ書き
objADW.Open
objADLF.Type = 2 'テキスト書き
objADLF.Charset = "Shift_jis"
objADLF.Open
objADLF.WriteText vbCrLf '改行コードをバッファに書く
objADLF.Type =1 'そのままバイナリモードに変更
objADLF.Position = 0 '０番地に位置づけ
binLF = objADLF.Read(2) 'バッファから２byte読みこむ
Do Until objADR.EOS = True
s = objADR.Read(recLen) '既知のレコード長ぶん読みこむ
objADW.Write s '読みこんだのをバッファに書く
objADW.Write binLF 'バイナリ改行コードをバッファに書く
Loop
objADW.SaveToFile (outF) 'バッファからファイルに出力
objADR.Close
objADW.Close
objADLF.Close
Set objFS = Nothing
Set objADR = Nothing
Set objADW = Nothing
Set objADLF = Nothing
嘘のようだがうまく行った。いえーい，バッバッ。
……。なーんか定数一発で済むトコロへものすごく阿呆な労力を割いた気がする……。ま・ま，これもひとつの富豪コーディングであろう。←絶対つかい方まちがい。
