ASPError オブジェクト

ASPError オブジェクトは、ASP ページのスクリプト内で発生したエラー状況に関する情報を取得します。ASPError オブジェクトは、Server.GetLastError メソッドから返されます。ASPError オブジェクトは、読み取り専用のプロパティを公開します。

構文

ASPError.property

プロパティ
ASPCode IIS で生成されたエラー コードを返します。
Number 標準 COM エラー コードを返します。
Source 可能である場合、エラーの原因となった行のソース コードを返します。
Category エラーが、ASPの内部、スクリプト言語、オブジェクトのどこで発生したかを示します。
File エラーが発生したときに処理していた .asp ファイルの名前を示します。
Line エラーを生成した .asp ファイル内の行を示します。
Column エラーを生成した .asp ファイル内の列を示します。
Description エラーの簡単な説明を返します。
ASPDescription ASP 関連のエラーである場合は、エラーの詳細な説明を返します。

解説

IIS で .asp ファイルのコンパイル中または実行中にエラーが発生すると、IIS は 500;100 カスタム エラーを生成します。既定では、すべての Web サイトおよびアプリケーションは、既定の .asp ファイルに 500;100 カスタム エラーの処理を転送します。IIS は、500;100 カスタム エラーを生成した後、エラー状況を示す ASPError オブジェクトのインスタンスも作成します。IIS スナップインを使用して 500;100 カスタム エラーの処理用の .asp ファイルを変更する方法については、「ASP エラー処理を有効にする」を参照してください。

例

次の例は、ファイル 500-100.asp の一部です。この例は、ASPError オブジェクトで公開されている情報を書き出す方法を示しています。

<%
  Response.Write objASPError.Category
  If objASPError.ASPCode > "" Then Response.Write ", " & objASPError.ASPCode
  Response.Write " (0x" & Hex(objASPError.Number) & ")" & "<br>"

  Response.Write "<b>" & objASPError.Description & "</b><br>"

  If objASPError.ASPDescription > "" Then Response.Write objASPError.ASPDescription & "<br>"

  blnErrorWritten = False

  ' Only show the Source if it is available and the request is from the same machine as IIS
  If objASPError.Source > "" Then
    strServername = LCase(Request.ServerVariables("SERVER_NAME"))
    strServerIP = Request.ServerVariables("LOCAL_ADDR")
    strRemoteIP =  Request.ServerVariables("REMOTE_ADDR")
    If (strServername = "localhost" Or strServerIP = strRemoteIP) And objASPError.File <> "?" Then
      Response.Write objASPError.File 
      If objASPError.Line > 0 Then Response.Write ", line " & objASPError.Line
      If objASPError.Column > 0 Then Response.Write ", column " & objASPError.Column
      Response.Write "<br>"
      Response.Write "<font style=""COLOR:000000; FONT: 8pt/11pt courier new""><b>"
      Response.Write Server.HTMLEncode(objASPError.Source) & "<br>"
      If objASPError.Column > 0 Then Response.Write String((objASPError.Column - 1), "-") & "^<br>"
      Response.Write "</b></font>"
      blnErrorWritten = True
    End If
  End If

  If Not blnErrorWritten And objASPError.File <> "?" Then
    Response.Write "<b>" & objASPError.File
    If objASPError.Line > 0 Then Response.Write ", line " & objASPError.Line
    If objASPError.Column > 0 Then Response.Write ", column " & objASPError.Column
    Response.Write "</b><br>"
  End If
%>
関連項目

Server.GetLastError

© 1997-2001 Microsoft Corporation.All rights reserved.