*************************************************************************
*fprintf2：streamにフォーマットデータを書込む				*
*	int		fprintf2(stream,format,...);			*
*	FILE		*stream;					*
*	const char	*format;					*
*vfprintf2：streamにフォーマットデータを書込む				*
*	int		vfprintf2(stream,format,arg);			*
*	FILE		*stream;					*
*	const char	*format;					*
*	va_list		arg;						*
*************************************************************************
* Copyright 1990 SHARP/Hudson	(1990/05/05)
* Arranged 1993 AIG-SOFT	(1993/04/24)

	xdef	_fprintf2
	xdef	_vfprintf2

	xref	_fputc
	xref	__fmtout2

	.offset	4
stream	ds.l	1
format	ds.l	1
arg1	ds.l	1

	.text
_vfprintf2:
	move.l	arg1(sp),-(sp)		. argment address
	bra	_fprint0
_fprintf2:
	pea	arg1(sp)		. argment address
_fprint0:
	move.l	format+4(sp),-(sp)	. format string
	move.l	stream+8(sp),-(sp)	. stream pointer
	pea	_fputc			. output function address
	jsr	__fmtout2		. formatter
	lea	16(sp),sp
	rts
