* 約1/60秒単位で指定時間待つ関数
* wait counterはV-DISPからとる。V-DISPは約1/60secである。
* int vwait(int time)
* '97/10/04 : より正確に1/60*time待つようにする(X68030対応)

	.include	defines.mac

	.text
	.xdef	_vwait		* Ｃインターフェース

_vwait:
	move.l	4(sp),d2	* 引数取り込み
	subq.l	#1,d2		* -1 for dbra
	moveq.l	#0,d1
	
	SUPERMODE		* SuperVisor mode(d0/a1破壊)
	move.l	d0,a1		* a1 <- SSP
	
	lea.l	GPIPCTRL,a0	* GPIP Contorol port
	bra	2f

1:	* wait next V-DISP
	addq.l	#1,d1
	btst.b	#4,(a0)		* ($e88001) bit4=V-DISP
	beq	1b
	
2:	* now in V-DISP
	addq.l	#1,d1
	btst.b	#4,(a0)		* ($e88001) bit4=V-DISP
	bne	2b
	
	dbra	d2,1b
	
	USERMODE		* to user mode(d0/a1破壊)
	move.l	d1,d0		* counter
	rts
*
	.end
