// FLOW / ROOTING '01.08
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

camera {
  location <0,0,-200>
  angle 60
  look_at <-20,10,0>
  }

light_source {<50,100,50> color rgb <1,1,1>}
light_source {<20,30,18> color rgb <1,1,1>}

#declare Cn =0; #while (Cn < 60)
  #declare R1 = seed(Cn*20);
  #declare Xr =-25+360*rand(0);
  #declare Yr =-15+360*rand(0);
  #declare Xp =0;
  #declare Yp =0;
  #declare Zp =0;
  #declare Ctm =100;
  #declare Ct =0; #while (Ct < Ctm)
    #declare Xr =Xr+30*rand(R1)-15;
    #declare Yr =Yr+30*rand(R1)-15;
    #declare R =1.2*(1-pow(Ct/Ctm,5));
    union {
      cylinder {<0,0,0>, <0,1,0>, R
        rotate <Xr,Yr,0> translate <Xp,Yp,Zp> rotate x*90
        }
      sphere { <Xp,Yp,Zp> R rotate x*90 }
      pigment {color rgb <0.1, 0.8, 0.3>}
      finish {
        ambient 0.2
        phong 0.3
        reflection 0.8
        diffuse 0.7
        }
      scale 2
      no_shadow
      }
    #declare Xp =Xp+sin(Xr*pi/180)*sin(Yr*pi/180);
    #declare Yp =Yp+cos(Xr*pi/180);
    #declare Zp =Zp+sin(Xr*pi/180)*cos(Yr*pi/180);
  #declare Ct = Ct+1; #end
#declare Cn = Cn+1; #end

sphere { <0,0,0> 50
  pigment {
    bumps
    turbulence 1
    lambda 0.5
    omega 0.2
    frequency 1
    color_map {
      [ 0.1  color rgbt <0.2,1,0.7,0.5> ]
      [ 0.4  color rgbt <0,0,0.3,0.6> ]
      }
    scale 15
    }
  finish {
    ambient 0.5
    phong 0.3
    reflection 0.8
    diffuse 0.7
    }
  no_shadow
  }