// Cruise / Jupiter-Europa '02.03
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

// Based on the data from The Nine Planets at http://www.nineplanets.org/

#version 3.1;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

// STARFIELD BACKGROUND
  // The galaxy include file containing "GALAXY.BG" and "Galaxy.sf" 
  // by Chris Colefax is downloaded from The POVRay Include Files Page
  // at http://www.geocities.com/SiliconValley/Lakes/1434/galaxy.html
  #declare galaxy_bgstars = 2;
  #declare galaxy_bgnebula = false;
  #declare galaxy_nebula_sphere = false;
  #include "GALAXY.BG"
  #declare star_count = 1000; //star_count = 100000;
  #declare star_scale = 0.15;
  #include "Galaxy.sf"

camera {
  location <680, 50, -100.0>
  look_at <-10000, 420, 600>
  angle 23.5
  }

union {

  //Sun
  light_source { <778330, 0, 0> color rgb <1.5, 1.5, 1.4> rotate y*60 rotate x*1.308 }

  //Jupiter
    // "jupiter1.png"'s original file is
    // Constructed by James Hastings-Trew and Constantine Thomas
    // from Voyager data (JPL/NASA)
    // downloaded from Constantine Thomas' Planetary Map Site
    // at http://www.evildrganymede.demon.co.uk/render/maps.htm
  sphere { <0, 0, 0> 142.984
    pigment{ image_map{ png "jupiter1.png" map_type 1 } }
    finish { ambient 0.2 }
    rotate y*-10 rotate x*-3.13
    } 

  #declare Media = media {
    emission 0.01
    intervals 100
    samples 1, 10 //samples 1, 100
    confidence 0.001
    variance 1
    density {
      spherical
      ramp_wave
      turbulence 0.8
      colour_map {
        [0 color rgbt <-2,-2,-2,1>]
        [0.5 color rgbt <1,1,1,0.5>]        }
      }
    }

  sphere {<0, 0, 0> 148
    pigment { color rgbf <1, 1, 1, 0.9> }
    finish { ambient 1 diffuse 0 }
    interior { media { Media } }
    hollow
    }

  //Io
    // "io.png"'s original file is
    // downloaded from Bjorn Jonsson's Planetary Map Site
    // at http://www.mmedia.is/~bjj/planetary_maps.html
  sphere { <0, 0, 0> 1.815
    pigment{ image_map{ png "io.png" map_type 1 } }
    finish { ambient 0.2 }
    rotate y*160 translate x*422 rotate y*20.5
    }

  //Europa
    // "europa.png"'s original file is
    // downloaded from Bjorn Jonsson's Planetary Map Site
    // at http://www.mmedia.is/~bjj/planetary_maps.html 
  sphere { <0, 0, 0> 1.569
    pigment{ image_map{ png "europa.png" map_type 1 } }
    finish { ambient 0.2 }
    rotate y*140 translate x*671 rotate y*9.2
    }

  //Ganymede
    // "ganymede.png"'s original file is
    // downloaded from Bjorn Jonsson's Planetary Map Site
    // at http://www.mmedia.is/~bjj/planetary_maps.html
  sphere { <0, 0, 0> 2.631
    pigment{ image_map{ png "ganymede.png" map_type 1 } }
    finish { ambient 0.2 }
    rotate y*300 translate x*1070 rotate y*165
    }

  //Callisto
    // "callisto.png"'s original file is
    // downloaded from Bjorn Jonsson's Planetary Map Site 
    // at http://www.mmedia.is/~bjj/planetary_maps.html
  sphere { <0, 0, 0> 2.4
    pigment{ image_map{ png "callisto.png" map_type 1 } }
    finish { ambient 0.4 }
    rotate y*30 translate x*1883 rotate y*168
    }

  rotate <21.6,-0,1>
  }