// SHELL / Like a Giant Clam '99.04
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings { assumed_gamma 2.2 }

#macro Texture_c (Cred, Cgreen, Cblue, Ctr)
  texture {
    pigment {color rgbt <Cred, Cgreen, Cblue, Ctr>}
    finish {
      ambient 0.3
      phong 0.3
      reflection 0.2
      specular 0.4
      brilliance 0.5
      irid {0.8 thickness 0.8 turbulence 0.1}
      }
    }
#end

#macro Shell_b (Ro, Nt, Rao, Rb, Na, Ho, Pxz)
  #declare Ra = pow(Rao,12/Nt);
  #declare Pne = 4*Nt*Nt;
  #declare Rt = pi*2/(Nt-0.5);
  #declare Yt = 2*pi/Nt/4/Nt;
  #macro Rs (P)
    0.85*Ro*pow(Ra,P)/Rb
  #end
  #macro Rl (P)
    0.7*Ro*pow(Ra,P)
  #end
  #macro Hl (P)
    Ho*pow(Ra,P*P)
  #end
  #macro Ka (P)
    12*Yt*pow(P,0.9)
  #end
  #macro Triangle_units (P1,P2,P3)
    smooth_triangle { 
      <cos(Ka(P1))*(Rs(P1)*cos(Rt*P1)+Rl(P1)),
        (Rs(P1)*cos(Rt*P1)+Rl(P1))*sin(Ka(P1))+0.1*Rs(P1)*cos(16*Rt*P1)/(1+3*pow(sin(Rt*P1/2),2)), 
        Pxz*Rs(P1)*sin(Rt*P1)+Hl(P1)>,
      <cos(Ka(P1))*cos(Rt*P1), sin(Ka(P1))*(1+0.05*sin(P1*30)), Pxz*sin(Rt*P1)*(1+0.05*cos(P1*30))>
      <cos(Ka(P2))*(Rs(P2)*cos(Rt*P2)+Rl(P2)),
        (Rs(P2)*cos(Rt*P2)+Rl(P2))*sin(Ka(P2))+0.1*Rs(P2)*cos(16*Rt*P2)/(1+3*pow(sin(Rt*P2/2),2)), 
        Pxz*Rs(P2)*sin(Rt*P2)+Hl(P2)>,
      <cos(Ka(P2))*cos(Rt*P2), sin(Ka(P2))*(1+0.05*sin(P2*30)), Pxz*sin(Rt*P2)*(1+0.05*cos(P2*30))>
      <cos(Ka(P3))*(Rs(P3)*cos(Rt*P3)+Rl(P3)),
        (Rs(P3)*cos(Rt*P3)+Rl(P3))*sin(Ka(P3))+0.1*Rs(P3)*cos(16*Rt*P3)/(1+3*pow(sin(Rt*P3/2),2)), 
        Pxz*Rs(P3)*sin(Rt*P3)+Hl(P3)>,
      <cos(Ka(P3))*cos(Rt*P3), sin(Ka(P3))*(1+0.05*sin(P3*30)), Pxz*sin(Rt*P3)*(1+0.05*cos(P3*30))>
      Texture_c (0.4*cos(Rt*P1)+0.2*sin(2*P1/Nt)+0.3+0.2*cos(P1*100),
        0.3*cos(Rt*P1)+0.3*sin(2*P1/Nt)+0.5+0.2*cos(P1*100), 1, 0)
        }
  #end                                                                union {
    #declare Pn =Nt+int(Nt/2);
    #while (Pn < Na*Pne-Nt)
      Triangle_units (Pn,Pn-1,Pn-Nt)
      Triangle_units (Pn,Pn-Nt+1,Pn-Nt)        
      #declare Pn =Pn +1;
    #end
    }     
#end                                                      

camera {
  location <0,200,-500>
  angle 1.5
  look_at <0, 0, 0>
  }

light_source {<500, 1000, 2000> color rgb <1,1,1>}
light_source {<0, -2000, -1000> color rgb <1,0,0>}

object {
  Shell_b (10,72,0.988,1.2,0.2,1,1.2)
  rotate z*160
  rotate y*120
  translate < -2.8,-3,0>
  }

background { color rgb <0, 0, 0.3> }