// QUALTIC2 - SPHERES by QUALTIC / A PROCESS '02.06
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 12
  assumed_gamma 2.2
  }

/* Quartic */
// a00 x^4   +a01 x^3 y +a02 x^3z   +a03 x^3    + a04 x^2y^2 + 
// a05 x^2yz +a06 x^2 y +a07 x^2z^2 +a08 x^2z   + a09 x^2    + 
// a10 xy^3  +a11 xy^2z +a12 xy^2   +a13 xyz^2  + a14 xyz    + 
// a15 xy    +a16 xz^3  +a17 xz^2   +a18 xz     + a19 x      + 
// a20 y^4   +a21 y^3z  +a22 y^3    +a23 y^2z^2 + a24 y^2z   + 
// a25 y^2   +a26 yz^3  +a27 yz^2   +a28 yz     + a29 y      + 
// a30 z^4   +a31 z^3   +a32 z^2    +a33 z      + a34        = 0

// (x^2+y^2+z^2-1)((x-A)^2+y^2+z^2-B^2)=C
#declare A=1.8; #declare B=0.1; #declare C=0.24;

union {
  quartic {
     < 1.0,  0.0,  0.0, -2*A,  2.0,
       0.0,  0.0,  2.0,  0.0,A*A-B*B-1,
       0.0,  0.0, -2*A,  0.0,  0.0,
       0.0,  0.0, -2*A,  0.0,  2*A,
       1.0,  0.0,  0.0,  2.0,  0.0,
 A*A-B*B-1,  0.0,  0.0,  0.0,  0.0,
       1.0,  0.0,A*A-B*B-1,0.0,-A*A+B*B-C > }
  light_source { <A+B*0.8, 0, 0> color rgb <2, 0, 0> }
  rotate <0, 20, 40>
  texture {
    pigment { color rgbt <0.4, 1, 0.4, 0.9> }
    finish {
      reflection 0.8
      phong 0.4
      phong_size 20
      ambient 0.3
      diffuse 0.8
      }
    }
  }

camera {
  location <0.0, 10.0, -28.0>
  angle 6
  look_at <A/2-0.6, 0.12, 0.0>
  }

light_source { <-200, 300, -300> color rgb <1, 1, 1> }