// Qualtic1 / Bulge
// Please use freely for non comercial purpose.
// All rights reserved by Tsutomu HIGO, Oct. 18, 1998

#version 3.0
global_settings { assumed_gamma 2.2 }

#declare Ca=0 #while (Ca<4)
  #declare Cb=0 #while (Cb<3)
    #declare A=Ca-1.1
    #declare B=Cb-1.1
    quartic { <
        1, 0, 0, -2*B, 2,   0, 2, -2, 0, -2+2*A+B*B,   0, 0, -2*B, 0, 0,
        2*B, 0, 2*B, 0, 2*B-2*A*B,   1, 0, 2, 6, 0,
        -1+2*A, 0, -2, 0, -2-2*A,   1, 0, 2-2*A, 0, 1-2*A+A*A
        >
      bounded_by {box{ <-3,-3,-2.5> <2,1,3> } }
      texture {
        pigment{ color rgb <0.9,0.2,0>}
        finish {
          reflection 0.4
          specular 0.5
          ambient 0.2
          phong 0.5
          diffuse 0.5
          }
        }
      no_shadow scale 1.5
      rotate <140,50,0>
      translate <Ca*8-11.4, Cb*8-8.8, 0>
      }
  #declare Cb = Cb+1 #end
#declare Ca = Ca+1 #end

sky_sphere {
    pigment {
      gradient y
      color_map {
        [ 0.2 color rgb <1,1,1> ]
        [ 1.00 color rgb <0.3,0.3,1> ]
        }
      scale 1 rotate y*0
      translate 0
      }
    }

light_source { <500, 500, -1000> color rgb <1,1,1> }

camera {
    location <0,0,-800>
    angle 2.5
    look_at <0, 0, 0>
    }