// NET / Disordering Triangle Net '00.11
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  assumed_gamma 2.2
  }

light_source {<-0.2, 0, 0> color <1,0,0>}
light_source {<0.2, 0, 0> color <0,1,0>}

camera {
  location <0,0,-10>
  angle 5.85
  look_at <0, 0, 0>
  }

#declare R1 = seed(7);
#declare Cos30 = cos(pi/6);

#macro Meshsquare(Pmaxx,Pmaxy,Rrand,Rsize)
  #declare Cp=array[Pmaxx][Pmaxy][3]

  #declare Xp=0; #while (Xp<Pmaxx)
    #declare Yp=0; #while (Yp<Pmaxy)
      #declare Modif=pow(pow(Xp-Pmaxx/2,2)+pow(Yp-Pmaxy/2,2),0.3)/pow(pow(Pmaxx/2,2)+pow(Pmaxy/2,2),0.3);
      #declare Cp[Xp][Yp][0]=(0.5*mod(Yp,2)+Xp-Modif*Rrand/2+Modif*Rrand*rand(R1))/Pmaxx-0.5-0.25/Pmaxx;
      #declare Cp[Xp][Yp][1]=Cos30*((Yp-Modif*Rrand/2+Modif*Rrand*rand(R1))/Pmaxx-0.5*Pmaxy/Pmaxx);
      #declare Cp[Xp][Yp][2]=0;
    #declare Yp=Yp+1; #end
  #declare Xp=Xp+1; #end

  union {
    #declare Xp=0; #while (Xp<Pmaxx)
      #declare Yp=0; #while (Yp<Pmaxy)
        sphere { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> Rsize/Pmaxx }
        #if (Yp>0) cylinder { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> <Cp[Xp][Yp-1][0],Cp[Xp][Yp-1][1],Cp[Xp][Yp-1][2]> Rsize/Pmaxx } #end
        #if (Xp>0) cylinder { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> <Cp[Xp-1][Yp][0],Cp[Xp-1][Yp][1],Cp[Xp-1][Yp][2]> Rsize/Pmaxx } #end
        #if (Yp>0) #if (Xp>-mod(Yp,2)) #if (Xp<Pmaxx-mod(Yp,2))
          cylinder { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> <Cp[Xp+2*mod(Yp,2)-1][Yp-1][0],Cp[Xp+2*mod(Yp,2)-1][Yp-1][1],Cp[Xp+2*mod(Yp,2)-1][Yp-1][2]> Rsize/Pmaxx }
        #end #end #end
      #declare Yp=Yp+1; #end
    #declare Xp=Xp+1; #end
    pigment {color rgbt <1,1,0,0.8>}
    finish {
      reflection 1
      phong 2
      brilliance 1
      ambient 0.4
      }
    no_shadow
    translate <0.5/Pmaxx,0.5/Pmaxx,0>
    }

#end

Meshsquare(20,15,0.8,0.06)