// HOSE / Statues '00.03
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 10
  assumed_gamma 2.2
  }

camera {
  location <40,20,-50>
  angle 75
  look_at <5, 30, 0>
  }

#declare Rndm = seed(59);

#declare Xmax=3*4+1;
#declare Ymax=3*4+1;
#declare Cplz=array[Xmax+1][Ymax+1]
#declare X=0; #while (X<Xmax+1)
  #declare Y=0; #while (Y<Ymax+1)
    #declare Cplz[X][Y]=abs(1.5-mod(X,3))+abs(1.5-mod(Y,3));
  #declare Y=Y+1; #end
#declare X=X+1; #end

//***************** Mesh treatment *****************
//triangle of the surface
#macro Trid (Ph,Pv)
  #declare Ph1=mod(Ph-1+Hmax,Hmax);
    triangle {
      <Cp[Ph][Pv][0],Cp[Ph][Pv][1],Cp[Ph][Pv][2]>
      <Cp[Ph1][Pv-1][0],Cp[Ph1][Pv-1][1],Cp[Ph1][Pv-1][2]>
      <Cp[Ph][Pv-1][0],Cp[Ph][Pv-1][1],Cp[Ph][Pv-1][2]>
      }
    triangle {
      <Cp[Ph1][Pv][0],Cp[Ph1][Pv][1],Cp[Ph1][Pv][2]>
      <Cp[Ph1][Pv-1][0],Cp[Ph1][Pv-1][1],Cp[Ph1][Pv-1][2]>
      <Cp[Ph][Pv][0],Cp[Ph][Pv][1],Cp[Ph][Pv][2]>
      }
#end

//normal vector of the point
#macro Vd (Ph,Pv)
  <(Cp[mod(Ph-1+Hmax,Hmax)][Pv][1]-Cp[Ph][Pv][1])*(Cp[Ph][Pv-1][2]-Cp[Ph][Pv][2])-(Cp[Ph][Pv-1][1]-Cp[Ph][Pv][1])*(Cp[mod(Ph-1+Hmax,Hmax)][Pv][2]-Cp[Ph][Pv][2]),
  (Cp[Ph][Pv-1][0]-Cp[Ph][Pv][0])*(Cp[mod(Ph-1+Hmax,Hmax)][Pv][2]-Cp[Ph][Pv][2])-(Cp[mod(Ph-1+Hmax,Hmax)][Pv][0]-Cp[Ph][Pv][0])*(Cp[Ph][Pv-1][2]-Cp[Ph][Pv][2]),
  (Cp[mod(Ph-1+Hmax,Hmax)][Pv][0]-Cp[Ph][Pv][0])*(Cp[Ph][Pv-1][1]-Cp[Ph][Pv][1])-(Cp[Ph][Pv-1][0]-Cp[Ph][Pv][0])*(Cp[mod(Ph-1+Hmax,Hmax)][Pv][1]-Cp[Ph][Pv][1])>
#end

//smooth_triangle of the surface
#macro Trisd (Ph,Pv)
  #declare Green = texture {
    pigment { color rgb<Pv/Zmax, 0.5+0.5*Pv/Zmax, 1-Pv/Zmax> }
      finish { reflection 0.8 ambient 0.2 phong 1 diffuse 0.5 brilliance 1 }
      normal {ripples 1 scale 30 frequency 15 }
    }
  #declare Ph1=mod(Ph-1+Hmax,Hmax);
    smooth_triangle {
      <Cp[Ph][Pv][0],Cp[Ph][Pv][1],Cp[Ph][Pv][2]> Vd(Ph,Pv)
      <Cp[Ph1][Pv-1][0],Cp[Ph1][Pv-1][1],Cp[Ph1][Pv-1][2]> Vd(Ph1,Pv-1)
      <Cp[Ph][Pv-1][0],Cp[Ph][Pv-1][1],Cp[Ph][Pv-1][2]> Vd(Ph,Pv-1)
  texture { Green}
      }
    smooth_triangle {
      <Cp[Ph1][Pv][0],Cp[Ph1][Pv][1],Cp[Ph1][Pv][2]> Vd(Ph1,Pv)
      <Cp[Ph1][Pv-1][0],Cp[Ph1][Pv-1][1],Cp[Ph1][Pv-1][2]> Vd(Ph1,Pv-1)
      <Cp[Ph][Pv][0],Cp[Ph][Pv][1],Cp[Ph][Pv][2]> Vd (Ph,Pv)
  texture { Green}
      }
#end

//***************** Hose coordinates *****************
#declare Rdgg=1;  //radius of arranging sphere

#macro Vrect (P)
  #if (Cc[P][2]-Cc[P-1][2]=0)
    #declare Cc[P-1][2]=Cc[P-1][2]-0.000001;
  #end
  #declare Vvx=Cc[P][0]-Cc[P-1][0];
  #declare Vvy=Cc[P][1]-Cc[P-1][1];
  #declare Vvz=Cc[P][2]-Cc[P-1][2];
  #declare Vvl=sqrt(Vvx*Vvx+Vvy*Vvy+Vvz*Vvz)+0.000001;
  #declare Vvx=Vvx/Vvl;
  #declare Vvy=Vvy/Vvl;
  #declare Vvz=Vvz/Vvl;
  #declare Vxz=(Cc[P-1][0]-Cc[P][0])/(Cc[P][2]-Cc[P-1][2]);
  #declare Vxl=sqrt(1+Vxz*Vxz);
  #declare Vxx=1/Vxl;
  #declare Vxy=0;
  #declare Vxz=Vxz/Vxl;
  #declare Vyz=-(Cc[P][1]-Cc[P-1][1])*(Cc[P][2]-Cc[P-1][2])/(pow(Cc[P][0]-Cc[P-1][0],2)+pow(Cc[P][2]-Cc[P-1][2],2));
  #declare Vyx=Vyz*(Cc[P][0]-Cc[P-1][0])/(Cc[P][2]-Cc[P-1][2]);
  #declare Vyl=sqrt(Vyx*Vyx+1+Vyz*Vyz);
  #declare Vyx=Vyx/Vyl;
  #declare Vyy=1/Vyl;
  #declare Vyz=Vyz/Vyl;
  #if (Cc[P][2]-Cc[P-1][2]<0)
    #declare Vxx=-Vxx;
    #declare Vxz=-Vxz;
  #end      
  #if (Cc[P][2]-Cc[P-1][2]=0)
    #declare Cc[P-1][2]=Cc[P-1][2]+0.000001;
  #end
#end

#macro Armm (Atwist, Pallx,Pally,Pallz, Vallys,Vallyc,Vallyd,Vallz)
#declare Z=0; #while (Z<Zmax+2)
    #declare Cc[Z][2]=30*(Z-1)/Zmax;
    #declare Cc[Z][1]=Rdgg*Vallys*sin(Z/Zmax*Vallyc*pi+Vallyd)-Rdgg*Vallys*sin(Vallyd);
    #declare Cc[Z][0]=Rdgg*Vallz*pow(Z/Zmax,4);
    #if (Z=0)
      #declare Zzmax=0;
      #declare Vvx=1;
      #declare Vvy=0;
      #declare Vvz=0;
      #declare Vxx=1;
      #declare Vxy=0;
      #declare Vxz=0;
      #declare Vyx=0;
      #declare Vyy=1;
      #declare Vyz=0;
   #else
      #declare Zzmax=0.999998*abs(Z-2)/Zmax+0.000001;
      Vrect (Z)
    #end
  #declare H=0; #while (H<Hmax)
    #declare Arot=45+Z/Zmax*Atwist; //twist
    #declare Hhmax=H/Hmax-Arot/360;
    #declare Cp[H][Z][3]=2*Rdgg*(1-Z/(Zmax+1))+0.000001+3*(1-cos(1.5*pi*2*Z/Zmax-0.25*pi*2))/(0.2+Z/Zmax);
    #declare Cp[H][Z][0]=Cc[Z][0]+Cp[H][Z][3]*(Vxx*cos(2*pi*Hhmax)+Vyx*sin(2*pi*Hhmax));
    #declare Cp[H][Z][1]=Cc[Z][1]+Cp[H][Z][3]*(Vxy*cos(2*pi*Hhmax)+Vyy*sin(2*pi*Hhmax));
    #declare Cp[H][Z][2]=Cc[Z][2]+Cp[H][Z][3]*(Vxz*cos(2*pi*Hhmax)+Vyz*sin(2*pi*Hhmax));
  #declare H=H+1; #end
#declare Z=Z+1; #end

mesh {
    #declare Z=2; #while (Z<Zmax+1)
    #declare H=0; #while (H<Hmax)
      Trisd (H,Z)
    #declare H=H+1; #end
    #declare Z=Z+1; #end
  rotate z*-90
  translate <Pallx,Pally,Pallz>
  }
#end

union{
  plane { z, 3 
    }
  #declare I=0; #while (I<1)
  #declare J=-30; #while (J<4)
//initialize the coordinates for mesh Cp(x,y,z,r)
#declare Zmax=32+J;
#declare Hmax=4;
#declare Cp=array[Hmax][Zmax+2][4]
#declare Cc=array[Zmax+2][3]        //Center of polar coordinates
#declare Z=0; #while (Z<Zmax+1)
  #declare Ii=0; #while (Ii<3)
    #declare Cc[Z][Ii]=0;
  #declare Ii=Ii+1; #end
#declare H=0; #while (H<Hmax)
  #declare Ii=0; #while (Ii<4)
    #declare Cp[H][Z][Ii]=0;
  #declare Ii=Ii+1; #end
#declare H=H+1; #end
#declare Z=Z+1; #end

    object {
      //Armm(Atwist, Pallx,Pally,Pallz, Vallys,Vallyc,Vallyd,Vallz)
      Armm (90*rand(Rndm), 10*I,15*J,0, 4,1+0.3*rand(Rndm),pi/2,1.5+0.5*rand(Rndm))
      scale <1,1,1.8+0.2*rand(Rndm)>
      }
  #declare J=J+2; #end
  #declare I=I+6; #end
    texture {
      pigment { color rgb<0, 0.5, 1> }
      finish { reflection 0.8 ambient 0.2 phong 1 diffuse 0.5 brilliance 1 }
      normal { ripples 1 scale 30 frequency 15 }
      }
   rotate x*-90
   no_shadow
   }
   
light_source {<100, 200, -200> color <1,1,1>}

background { color rgb <0,0,0.2> }

fog {
  fog_type 2
  fog_alt 6
  fog_offset 0
  distance 30
  color rgb <0.6,0.4,1>
  }