// Plant '98.06
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.0
global_settings { assumed_gamma 2.2 }

#include "colors.inc"

camera {
    location <30, 0, -60>
    angle 45
    look_at <0, 5, 0>
    }

light_source {<50, 100, 50> color White}
light_source {<20, 30, 18> color White}

#declare Oleaf = intersection {
    sphere { <1, 0, 1.732> 2.01 }
    sphere { <1, 0, 1.732> 2 inverse}
    box{ <0, 0, 0> < 2,  2, -2> rotate x*-10}
    box{ <0, 0, 0> < 2, -2, -2> rotate x*10}
    }

#declare Cno =12
#declare Cn =0 #while (Cn <Cno)
  #declare Xr =Cn/Cno*50
  #declare Yr =Cn*210
  #declare Xp =0
  #declare Yp =-Cn/10
  #declare Zp =0
  #declare Cto =30
  #declare Ct =0 #while (Ct < Cto)
    #declare Xr =Xr+3+Ct/Cto*2
    #declare Yr =Yr
    merge {
        cylinder {<0,-0.05,0>,<0,1.05,0>, 0.3*(1-Ct/Cto)+0.05 scale z*0.7}
        object { Oleaf scale <5*sin((15+155*Ct/Cto)/180*pi), 5, 5*sin((15+155*Ct/Cto)/180*pi)> rotate z*Ct/Cto*70}
        object { Oleaf translate x*-2 scale <5*sin((15+155*Ct/Cto)/180*pi), 5, 5*sin((15+155*Ct/Cto)/180*pi)> rotate z*-Ct/Cto*70}
        rotate <Xr,Yr,0> translate <Xp,Yp,Zp>
        pigment {color rgb <0.4+0.4*Ct/Cto-Cn/Cno*0.2, 0.6+0.4*Ct/Cto-Cn/Cno*0.3, 0>}
        finish {
            ambient 0.3
            crand 0.1
            reflection 0.3
            specular 1.0
            brilliance 1.0
            }
        }
    #declare Xp =Xp+sin(Xr*pi/180)*sin(Yr*pi/180)
    #declare Yp =Yp+cos(Xr*pi/180)
    #declare Zp =Zp+sin(Xr*pi/180)*cos(Yr*pi/180)
  #declare Ct = Ct+1 #end
#declare Cn = Cn+1 #end

sky_sphere {
    pigment {
        gradient y
        color_map {
            [ 0.5  color LightSteelBlue ]
            [ 1.0  color White ]
            }
        scale 2
        translate -1
        }
    }