// Chaos1 / The Lorenz Attractor Basic '00.05
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
#global_settings { assumed_gamma 2.2 }

camera {
  location  <150, 100, -10>
  look_at <0, 5, -3>
  angle 39
  }

#macro Chaos ( Xo, Yo, Zo, H, A, B, C, Nend )
  #declare X = Xo;
  #declare Y = Yo;
  #declare Z = Zo;
  #declare N = 0;  #while (N < Nend)
    #declare X1 = X + H*A*(Y-X);
    #declare Y1 = Y + H*(X*(B-Z)-Y);
    #declare Z1 = Z + H*(X*Y-C*Z);
    cylinder {
      <X, Y, Z> <X1, Y1, Z1> 0.3
      pigment { color rgb < 0.8*N/Nend, 0.3, 1.5 > }
      finish { reflection 0.5 ambient 0.3 phong 1 diffuse 1 brilliance 1}
      no_shadow
      }
    #declare X = X1;
    #declare Y = Y1;
    #declare Z = Z1;
  #declare N = N+1;  #end
#end

union { Chaos ( 0.1, 0, 0, 0.005, 10, 28, 8/3, 10000 ) translate z*6 rotate y*150}
union { Chaos ( 12, 15, -5, 0.005, 10, 28, 8/3, 10000 ) translate z*6 rotate y*270}
union { Chaos ( 0.3, 0, -2, 0.005, 10, 28, 8/3, 10000 ) translate z*6 rotate y*30}

light_source {
  <700, 1000, -3000>
  color rgb <0.8,1.5,0.8>
  }