// Chaos1 / The Lorenz Attractor Curve  '00.05
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
#global_settings { assumed_gamma 2.2 }

camera {
  location  <300, 100, -10>
  look_at <0, 5, -3>
  angle 30
  }

#macro Chaos ( H, A, B, C, Nstart, Nend )
  #declare X = 0.1;
  #declare Y = 0;
  #declare Z = 0;
  #declare N = Nstart;  #while (N < Nend)
    #declare X1 = X + H*A*(0.5*Y-X);
    #declare Y1 = Y + H*(X*(B-Z)-0.5*Y);
    #declare Z1 = Z + H*(1.2*X*Y-C*Z);
    cylinder {
      <X, Y, Z> <X1, Y1, Z1> 0.5
      pigment { color rgb <(N-Nstart)/(Nend-Nstart), 0, 1-(N-Nstart)/(Nend-Nstart) > }
      finish { reflection 0.5 ambient 0.6 phong 3 diffuse 3 brilliance 1}
      no_shadow
      }
    #declare X = X1;
    #declare Y = Y1;
    #declare Z = Z1;
  #declare N = N+1;  #end
#end

union { Chaos ( 0.0045, 60.0, 60, 8/5, -1000, 3000 )
  translate y*-30
  rotate y*210
  }
union { Chaos ( 0.002, 1.6, 50, 8/6, -1000, 3000 )
  translate <0,20,-10>
  rotate y*30
  }

light_source {
  <700, 1000, -3000>
  color rgb <1,1,1>
  }