// Persistence Of Vision raytracer version 3.0
// Flower and Fish by bicubic_patch
// sample file by T.Higo  09.1997, 10.1997

camera { location < 2, 5, -4 > look_at < 0.2, 0.5, 0 > }

light_source { <350, 200, -120> color < 1, 1, 1 > }

//*****  Flower  *****

#declare Leef =
  object {
  bicubic_patch { type 1
     flatness 0.01
     u_steps 4
     v_steps 4
      <0, -7.2, -0.2>, <1, 1.7, -1.0>, <2, 2.3, -1.2>, <   3, 1.5, -0.03>,
      <0, -7.0, -0.1>, <1, 1.2, -0.3>, <2, 2.2, -0.4>, < 3.2, 1.6, -0.01>,
      <0, -7.0,  0.1>, <1, 1.4,  0.3>, <2, 2.1,  0.4>, < 3.1, 1.5,  0.01>,
      <0, -7.2,  0.2>, <1, 1.6,  1.0>, <2, 2.4,  1.2>, <   3, 1.4,  0.03>
     pigment { color red 1.0 green 0.7 blue 0.8 }
      }
     finish { ambient 0.4 diffuse 0.6 phong 0.2 }
     rotate < 0, 0, 0 >
     scale 1
  }

union
  { object {Leef rotate < 0,   0, 0 > }
    object {Leef rotate < 0,  90, 0 > }
    object {Leef rotate < 0, 180, 0 > }
    object {Leef rotate < 0, 270, 0 > }
  }


//*****   Fish   *****
#declare Xmb =-2.5
#declare Ymb =-0.2
#declare Zmb =-2.8
#declare Xmt =-2.55
#declare Ymt = 0.2
#declare Zmt =-2.8

#declare Xbb =-0.5
#declare Ybb =-1.7
#declare Zbb =-0.5
#declare Xbt =-0.5
#declare Ybt = 2.0
#declare Zbt =-0.5

#declare Xhb = 2.0
#declare Yhb =-0.2
#declare Zhb =-0.2
#declare Xht = 2.0
#declare Yht = 0.1
#declare Zht = 0.2

#declare Xtb = 3.3
#declare Ytb = 1.0
#declare Ztb =-1.0
#declare Xtt = 3.1
#declare Ytt =-0.8
#declare Ztt =-0.85

#declare Fishl =
  object {
  bicubic_patch { type 1
     flatness 0.01
     u_steps 4
     v_steps 4
     <Xmb,Ymb,Zmb>, <Xbb,Ybb,Zbb>, <Xhb,Yhb,Zhb>, <Xtb,Ytb,Ztb>,
     <Xmb+0.2,(2*Ymb+Ymt)/3,Zmb-0.1>, <Xbb,(2*Ybb+Ybt)/3,Zbb-1.0>, 
     <Xhb,(2*Yhb+Yht)/3,Zhb+0.1>, <3.0,(2*Ytb+Ytt)/3,(2*Ztb+Ztt)/3+0.01>,
     <Xmt,(Ymb+2*Ymt)/3,Zmb-0.1>, <Xbt,(Ybb+2*Ybt)/3,Zbt-0.7>, 
     <Xht,(Yhb+2*Yht)/3,Zht-0.1>,<Xtt-0.2,(Ytb+2*Ytt)/3,(Ztb+2*Ztt)/3-0.01>,
     <Xmt,Ymt,Zmt>, <Xbt,Ybt,Zbt>, <Xht,Yht,Zht>, <Xtt,Ytt,Ztt>
      }
  }

#declare Fishr =
  object {
  bicubic_patch { type 1
     flatness 0.01
     u_steps 4
     v_steps 4
     <Xmb,Ymb,Zmb>, <Xbb,Ybb,Zbb>, <Xhb,Yhb,Zhb>, <Xtb,Ytb,Ztb>,
     <Xmb+0.2,(2*Ymb+Ymt)/3,Zmb+0.1>, <Xbb,(2*Ybb+Ybt)/3,Zbb+1.0>, 
     <Xhb,(2*Yhb+Yht)/3,Zhb-0.1>, <3.0,(2*Ytb+Ytt)/3,(2*Ztb+Ztt)/3-0.01>,
     <Xmt,(Ymb+2*Ymt)/3,Zmb+0.1>, <Xbt,(Ybb+2*Ybt)/3,Zbt+0.7>, 
     <Xht,(Yhb+2*Yht)/3,Zht+0.1>,<Xtt-0.2,(Ytb+2*Ytt)/3,(Ztb+2*Ztt)/3+0.01>,
     <Xmt,Ymt,Zmt>, <Xbt,Ybt,Zbt>, <Xht,Yht,Zht>, <Xtt,Ytt,Ztt>
      }
  }

union
  {
     object {Fishl}
     object {Fishr}
     pigment { color red 0.5 green 0.7 blue 1.0 }
     finish 
     { 
     specular 1.0
     crand 0.1
     reflection 1.1
     brilliance 1.0
     ambient 0.4
     diffuse 0.6
     phong 0.2
     }
     scale 0.3
     rotate < 10, -30, 0 >
     translate < 1.5, 2.7, 0 > 
  }