char c      :// 宣言のみ
char c='A'  :// 初期値 'A' 代入付き宣言
char d=c+1  :// 初期化式では、宣言済みの別変数も参照できる

int i
int j=0
int k=i+j

float f1=3.14
float f2=pi(1)  :// 初期化で関数による代入も出来る
float f3=f1+f2

str s1
str s2="String"
str s3="3rd "+s2

dim int a(10)           :// 11個のint型1次元配列を確保する。各要素の初期値は0
dim char b(10)={0,1,2}  :// 要素数を超えない範囲で初期値を与える。初期値指定がない部分は0になる
dim str  c(3)           :// str型配列の初期値は空文字列
c={"A","B","C","D"}     :// 宣言の後、任意の場所で代入出来る。
c={"A",
   "B","C",         // 複数行にまたがって記述することも出来る
   "D"
}

dim float x(3,2)    :// 2次元配列；1次元目要素数3+1、2次元目要素数2+1
// 多次元配列への代入の場合も、すべて一組の{}の中に記述する
// (C言語のように、次元別に{}で区切る必要はない)
x={10,20,30,40,     // x(0,0)～x(3,0)に格納
   11,21,31,41,     // x(0,1)～x(3,1)
   12,22,32,42      // x(0,2)～x(3,2)
}           :// 格納順は1次元目から順(C言語とは記述順が逆になるので注意)

「間違い」
dim str pai(3)={            :// コメント
     "一二三四五六七八九"   :// コメント
}

「正解」
dim str pai(3)={            // コメント
     "一二三四五六七八九"   // コメント
}

enum
    CONST1  // 省略時の初期値は0
    CONST2
endenum
// CONST1=0,CONST2=CONST1+1=1となる

enum
    CONST1=10
    CONST2
endenum
// CONST1=10,CONST2=CONST1+1=11となる

enum
    CONST1=1
    CONST2=CONST1*10    // 定義済み定数の参照および演算子は使える
endenum
// CONST1=1,CONST2=CONST1*10=10となる

int a=5
enum
    CONST1=bit(0)   // エラー；関数は使えない
    CONST2=a*10     // エラー；変数は参照できない
endenum

case CONST1 // OK
case a      // エラー；変数はcase値に使えない

if val(basicVersion$)<=3.0 then {
    // v3.0より上でも常に定義される
    enum
        CONST1
        CONST2
    endenum
}

「例」
enum
  WW=3
endenum
〜
func f(masu(WW,WW);int):// エラー発生

fenum
    FCONST1=3.141592
    FCONST2
endenum
// FCONST1=3.141592,FCONST2=FCONST1+1.0=4.141592となる

fenum
    FCONST1=10.10
    FCONST2=FCONST1*10    // 定義済み定数の参照および演算子は使える
endenum
// FCONST1=10.10,FCONST2=FCONST1*10=1010.0となる

for int変数=開始値 to 終了値
    ～処理～
next

int変数を開始値から終了値まで+1ずつ増加させながらループする(増分を変更する構文はない)。
変数はint型以外使えないので注意(charもだめ)。

終了値<開始値の時はループは実行されない。

int i
for i=0 to 5
  print "i=";i;","; :// i=0,1,2,3,4,5, と表示される
next
print

forとnextは常に1:1で対応する。
旧MS系BASICのように、nextの後に複数の変数名を列記することで、

複数のforを１つのnextで受けることは出来ない。
（nextの後に変数名を記述してはいけない。）

repeat
    ～処理～
until 終了条件式

終了条件式が真になるまで、処理を繰り返す。
条件式がループ末尾にあるので、処理は最低1回は実行される。

i=0
repeat
  print "i=";i;","; :// i=0,1,2,3,4,5, と表示される
  i=i+1
until i=5+1     :// i=5+1になったら終了する
print

while 条件式
    ～処理～
endwhile

条件式が真の間、処理を繰り返す。
条件式が最初にあるので、処理は1回も実行されないこともある。

｢例1｣
i=0
while i<5+1     :// i<5+1の間ループする
  print "i=";i;","; :// i=0,1,2,3,4,5, と表示される
  i=i+1
endwhile
print

｢例2｣
i=10
while i<5+1      :// このループは実行されない
  print "i=";i;",";
  i=i+1
endwhile
// すぐにここに飛んでくる

switch 式
case 定数1
    処理1
    [break]
case 定数2
    処理2
    [break]
    ･
    ･
[default[: 処理n]]
endswitch

式の結果、定数値別に処理を実行する。
整数定数と文字列で使うことが出来る。
これを「数値型switch」および「文字列型switch」と呼ぶ。

「数値型switch」のcase値にはenum値を含む整数定数が、
「文字列型switch」のcaseにはstr定数が使える。
変数や式は使えない。

式がchar/floatを含む場合、自動的にintに変換される。
従って、数値型switchでは、式の(結果として期待する)型にかかわらず、case値は整数値でなくてはならない。

文字列の場合、スペース未満の文字コードを持つの文字を含めることは出来ない

処理の中にbreakを記述すると、そこでendswitchに飛ぶ。
式の結果がどのcaseにもあてはまらないとき、defaultへ飛ぶ。
defaultは最後のcase文の下に記述する必要がある(C言語では配置は自由だが、X-BASICには制約がある)。

C言語とは違い、case 値/defaultの後ろに':'は必須ではない。
(':'を記述すると、マルチステートメントと見なされる。)

1つのswitch～endswitchの中には、最大256個のcaseを置くことが出来る。
1つのswitch～endswitchの中では、defaultは1つしか置けない。

｢例１｣数値型switch
int i
for i=0 to 5
  switch i
    case 0      :// ここはi=0の時だけ飛んでくる
      print "0"
      break
    case 1
    case 2      :// ここはi=1と2の時処理される
      print "1/2"
      break

    default     :// iが上記以外の時飛んでくる
      print "その他"
      break
  endswitch
next


｢例２｣文字列型switch
str s
input "文字列=";s
// dim str menues(3)={"A","BC",DEF","GHI"}
// s=menues(selectMenu("文字列",menues))
switch s
  case "A"      :// ここはs="A"の時だけ飛んでくる
    print "s = A"
    break
  case "BC"
  case "DEF"    :// ここはs="BC"または"DEF"のとき処理される
    print s;"<"
    break

  default       :// sが上記以外の時飛んでくる
    print s
    break
endswitch

for i=0 to 10
    if i>=5 then continue
    print "i=";i    :// i>=5になったら、ここは実行されない
next

for i=0 to 10
    if i=5 then break   :// i=5になったら、forループを終了する
    print "i=";i
next

｢例1｣1行で記述する。elseなし
if a=1 then print "a=1"

「例2」1行で記述する。elseあり
if a=1 then print "a=1" else print "a<>1"

注意）else以降を別行にしてはいけない
×  if a=1 then print "a=1"
    else print "a<>1"

「例3」真時処理を複数行で記述する
if a=1 then {
    print "a=1"
    ～処理～
}

「例4」真/偽時処理ともに複数行で記述する
if a=1 then {
    print "a=1"
    ～処理～
} else {
    print "a<>1"
    ～処理～
}

ラベルは記述位置ではなく、その行の先頭に対して設定される。
従って、
    label "A":print "label A"
    print "label A":label "A"
この2つの記述は、同じ意味になる。

｢例1｣
for i=0 to 10
  for j=0 to 10
    if i=5 and j=5 then goto *loopout:// 2つのforループを一気に抜ける
  next
next
*loopout

「例2」
switch n
    case 1
      print "1"
      goto "L1"
    case 2
      print "2"
      goto "L1"
    default
      print "その他"
    label "L1"
      ～共通処理～
      break
endswitch

func [関数の型] 関数名([引数;引数の型,･･･])
    return[(戻り値)]
endfunc

内部関数定義。
詳細は前述の通り。

print 変数[;]
    変数の内容を表示する。

print "文字列"[;]
    文字列を表示する。

print 式1;式2;･･･;式n[;]
    複数の式の結果をならべて表示する。

print 式1,式2,･･･,式n[,]
    複数の式の結果を、8文字間隔(TAB相当)でならべて表示する。
    最後に','を付けた場合、改行しない。
    グラフィック座標モードではタブではなくスペース1文字で並べられる。

式には数値と文字列を混在させることも出来る。
それぞれ、後ろに';'を付けた時は改行しない。

print
    改行のみ行う。

• 文字列中にコントロールコードが含まれている場合、以下のように処理されます。
  • テキスト座標モードではコントロールコードは全て無視されます
  • グラフィック座標モードでは文字列全体が表示されません
  いずれも高速化のためです。
  print "文字列"+chr$(コントロールコード)と記述した場合、
  "文字列"+chr$(コントロールコード)は文字列結合で1文字列と見なされるため、 コントロールコードは無視されます。
• 表示コントロールコードは、その1文字だけをprintした場合にのみ実行されます。
  ただし、print "文字列";chr$(コントロールコード)と記述した場合は、';'で表示が区切られているので、
  コントロールコードは実行されます(','でも同様)。
• 短い間隔(1秒以下)で同じ位置にprintすると、表示が瞬くことがあります。

書式付きで数値を表示する。
書式文字列は、以下の文字群の組み合わせで構成される。この文字列は定数でなくてはならない。

using内では書式指定文字と普通文字を混在することも出来る。
普通文字はそのまま表示される。
書式指定の数と必要な式の数は同じでなくてはならない。

指定            表示結果
"+####";0       "   +0"     :// 0でも符号が付きます
"+####";10      "  +10"
"+####";-10     "  -10"
"####-";0       "   0 "     :// 0には符号が付きません
"####-";10      "  10 "
"####-";-10     "  10-"
"+%%%%";0       "+0000"     :// 0でも符号が付きます
"+%%%%";10      "+0010"
"+%%%%";-10     "-0010"
"%%%%-";0       "0000 "     :// 0には符号が付きません
"%%%%-";10      "0010 "
"%%%%-";-10     "0010-"

"+###.####"   前に符号付き、整数3桁＋小数4桁
"**#,####-"   整数2+1+4=7桁、それに満たない場合は*で埋める、3桁ごと,区切り、後ろ符号付き

print using "マップ幅：##×##  時間：#####";wx,wy,dt    :// 書式指定3つに変数3つなので正しい
print using "マップ幅：##×##  時間：";wx,wy,dt         :// 書式指定2つに変数3つなのでエラーになる

print using "#";v;:print ,

書式付きで文字列を表示する。
書式文字列は、以下の文字群の組み合わせで構成される。文字列定数でなければならない。

using内では書式指定文字と普通文字を混在することも出来る。
普通文字はそのまま表示される。
書式指定の数と必要な式の数は同じでなくてはならない。

キーボードからデータを変数に代入する。
変数はすべての型が指定できる。

メッセージを指定した場合は、入力前にそれが表示される。
メッセージは固定文字列でなくてはならず、文字列変数(相当)では与えられない。
必要なら、print で文字列変数を表示した直後にinputを実行すること。
    「例」
    print message$;:input a
入力欄は、メッセージを除いた１行終端までとなる。
したがって、メッセージが長すぎて１行に収まらないときは入力できなくなるので注意。

inputではキーボードのタイプを指定することは出来ない(KeyboardTypeNumbersAndPunctuation固定)。
必要なら、inputWithPlaceholder()を使うこと。

複数の変数を指定することも出来る。
入力は','で区切って列記する。
この場合、必要な個数を同時に入力する必要がある。
されてない場合は入力が、繰り返し催促される。
変数の型は異なる物が混在してもかまわない。

各入力に対しては正しい型となる入力を与えなければならない。
正しくない場合、再入力を求められる。

｢例１｣
int a
input "a=";a    :// int変数aに入力

｢例２｣
int a
str s
input "a,s=";a,s    :// int変数aと文字列変数sに同時入力する
            :// 以下の場合、入力が繰り返されます
            :// (1)同時に2つの入力がない
            :// (2)aに数値として正しくない入力をしようとした

キーボードからデータを文字列変数に代入する。
但し変数はstr型で、１つでなくてはならない。
inputと違い、,(カンマ)、"(引用符)、'(シングルクオーテーション)を含む全ての文字を入力できる。
メッセージを指定した場合は入力時にそれを表示する。

str s
linput "s=";s