// FLOW / LOOKING BACK '01.08
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

camera {
  location <10,-5,-30>
  angle 40
  look_at <0,11,0>
  }

light_source {<-50,100,-50> color rgb <1,1,1>}
light_source {<-20,30,-18> color rgb <1,1,1>}

#declare Cn =0; #while (Cn < 30)
  #declare Rb =0;
  #declare R1 = seed(Cn*20);
  #declare Xr =120+30*rand(0);
  #declare Yr =30+20*rand(0);
  #declare Xp =0;
  #declare Yp =0;
  #declare Zp =0;
  #declare Ctm =80;
  #declare Ct =0; #while (Ct < Ctm)
    #declare Xr =Xr+10*rand(R1);
    #declare Yr =Yr+5*rand(R1);
    #if(Ct<Ctm/2) #declare R =0;
      #else       #declare R =0.7*pow(Ct/Ctm,4);
      #end
    union {
      cone { <0,0,0>, Rb, <0,1,0>, R
        rotate <Xr,Yr,0> translate <Xp,Yp,Zp> rotate x*90 }
      sphere { <0,1,0> R
        #if(Ct=Ctm-1)
          translate y*-1
          scale <1,4,1>
          translate y*1
          #end
        rotate <Xr,Yr,0> translate <Xp,Yp,Zp> rotate x*90
        }
      pigment {color rgb <1,0.8,0.6>}
      finish {
        ambient 0.3
        phong 0.8
        reflection 1
        }
      scale 0.5 rotate y*240 rotate z*70
      no_shadow
      }
    #declare Rb =R;
    #declare Xp =Xp+sin(Xr*pi/180)*sin(Yr*pi/180);
    #declare Yp =Yp+cos(Xr*pi/180);
    #declare Zp =Zp+sin(Xr*pi/180)*cos(Yr*pi/180);
  #declare Ct = Ct+1; #end
#declare Cn = Cn+1; #end

sky_sphere {
  pigment {
    gradient y
    color_map {
      [ 0.5  color rgb <1,0,0> ]
      [ 1.0  color rgb <0,0,0> ]
      }
    scale 2
    rotate z*-30 translate -1
    }
  }