// Cruise / Earth '02.03
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

// Based on the data from The Nine Planets at http://www.nineplanets.org/

#version 3.1;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

camera {
  location <2000, -1500, 0>
  look_at <200, 120, 50>
  angle 12
  }

// STARFIELD BACKGROUND
  // The galaxy include file containing "GALAXY.BG" and "Galaxy.sf" 
  // by Chris Colefax is downloaded from The POVRay Include Files Page
  // at http://www.geocities.com/SiliconValley/Lakes/1434/galaxy.html
   #declare galaxy_bgstars = 2;
   #declare galaxy_bgnebula = false;
   #declare galaxy_nebula_sphere = false;
   #include "GALAXY.BG"
   #declare star_count = 1000; //star_count = 150000;
   #declare star_scale = 0.1;
   #include "Galaxy.sf"

union {
  //Sun
  light_source { <149600, 0, 0> color rgb <0.9, 0.9, 1>  rotate y*220 }

  //Earth
  sphere { <0, 0, 0> 384.4
    pigment{ image_map { png "earthc.png" map_type 1 } }
    finish { ambient 0.01  phong 0.3 diffuse 1 }
    rotate y*230 rotate x*23.45
    }

  #declare Media = media {
    emission 0.05
    intervals 5
    samples 1, 10 // samples 1, 1000
    confidence 0.9999
    variance 1/1000
    density {
      spherical
      ramp_wave
      turbulence 0.01
      color_map {
        [0.11 color rgbt <0, 0, 0, 1>]
        [0.135 color rgbt <0, 0, 0.1, 0.8>]
        [0.25 color rgb <0.8, 0.8, 1>]
        }
      }
    }

  sphere { 0, 1
    pigment { color rgbf<1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    scale 460
    hollow
    }

  rotate y*90 rotate z*-10
  }