// WIND / ISLANDS '99.06
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 30
  assumed_gamma 2.2
  }
 
light_source {<10, -30, -30> color <1,1,1>}

camera {
  location <0,-10,-3>
  angle 75
  look_at <0, -1, 0>
  }
  
//Map
sphere { <0,0,500> 500
  pigment { wrinkles
    color_map{ 
      [0 color rgbt <2,2,2,0>]            //top
      [0.1 color rgbt <1,0.8,0.3,0.2>]    //rock
      [0.15 color rgbt <0.3,1,0,0.1>]     //forest
      [0.25 color rgbt <1.,1.8,0,0.1>]    //plane
      [0.315 color rgbt <0.8,0.7,0.6,0.1>]//rock
      [0.32 color rgbt <2,2,2,0.1>]       //wave
      [0.45 color rgbt <0,1.7,2,0.5>]     //water
      [1 color rgbt <2,0,10,1>]           //sea
      }
    turbulence 1.5
    scale 10
    }
  }

//Clouds            
sphere { <0,0,500> 502
  pigment { wrinkles
    color_map{ 
      [0 color rgbt <10,10,10,0.65>]  
      [0.3 color rgbt <3,3,3,0.8>]  
      [0.35 color rgbt <1,1,1,0.9>] 
      [0.37 color rgbt <0.3,0.3,1,1>] 
      }
    turbulence 0.5
    translate <0,5,0>
    scale <1,1.5,1>
    rotate z*-60
    scale 5
    }
  }

sphere { <0,0,500> 501.6
  pigment { wrinkles
    color_map{ 
      [0 color rgbt <10,10,10,0.83>] 
      [0.4 color rgbt <3,3,3,0.84>]  
      [0.55 color rgbt <1,1,1,0.92>] 
      [0.6 color rgbt <0.3,0.3,1,1>] 
      }
    turbulence 5.5
    translate <10,0,0>
    scale <1,1.5,1>
    rotate z*-60
    scale 20
    }
  }

background { color rgb <0.3,0.3,1> }