// STRATA / Flagment '01.09
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 3
  assumed_gamma 2.2
  }

camera {
  location <0, 500, 0>
  angle 42
  look_at <0, 0, 0>
  }

light_source {<0, 5, 0> color rgb <1,1,1>}

#declare R1 = seed(15);
#declare Ctm = 75;
#declare Turn = array[Ctm]
#declare Cnm = 10;
#declare Bubble = array[2]
#declare R = 0;

#declare Ct = 0; #while (Ct < Ctm)
  #if(Ct=0)
    #declare Turn[Ct] = 0;
  #else
    #declare Turn[Ct] = Turn[Ct-1]-15*rand(R1)+45*rand(R1)-10;
  #end
#declare Ct = Ct+1; #end

#declare Cn = 0; #while (Cn < Cnm)
  #declare N = 0; #while (N < 2)
    #declare R = R+6*rand(R1);
    #declare Xp = 0;
    #declare L = 7;
    #declare Yp = 0;
    #declare Zp = 0;
    #declare Bubble[N] = union {
      #declare Ct = 0; #while (Ct < Ctm)
      #declare Yr = Turn[Ct];
      sphere { <Xp,Yp,Zp> R }
      #declare Xp = Xp+L*sin(mod(Yr+360,360)*pi/180);
      #declare Yp = Yp+0;
      #declare Zp = Zp+L*cos(mod(Yr+360,360)*pi/180);
    #declare Ct = Ct+1; #end
    }
  #declare N = N+1; #end
  intersection {
    object { Bubble[1] }
    object { Bubble[0] inverse }
    plane { y, 0 }
    pigment {color rgb <0.2*rand(R1), 0.4*rand(R1), 0.5+0.5*rand(R1)>}
    finish {
      ambient 0.2
      phong 0.3
      reflection 1
      diffuse 0.7
      }
    translate x*-90 rotate y*120
    no_shadow
  }
#declare Cn = Cn+1; #end