// Spheres / Oscillation
// Please use freely for non comercial purpose.
// All rights reserved by Tsutomu HIGO, Oct. 11, 1998
//
// *CAUTION
//      This scene requires large RAM for high quality.
//      Please adjust the number of spheres by the increasing value
//      of parameter A.

#version 3.0
global_settings { assumed_gamma 2.2 }

camera {
   location <0,0,-100>
   angle 45
   look_at <0, 0, 0>
   }

light_source {<50, 100, -50> color rgb <1,1,1>}

#declare Rl =5
#declare Rs =0.6
#declare Tx =1 #while (Tx<6)
  #declare Ty =1 #while (Ty<5)
    union {
      #declare A =0 #while (A<6.3)
        #declare Cx =Rl*cos(A*Ty)
        #declare Cy =Rl*cos(A*Tx)
        #declare Cz =Rl*sin(A*Ty)
          sphere { <Cx,Cy,Cz> Rs
          texture {
            pigment {color rgb <sin(A)/2+0.5, -cos(A)/2+0.5, cos(A)/2+0.5>}
            finish {ambient 0.4}
            }
          }
        #declare A = A+0.02 #end // I rendered Gallery's image by "A = A+0.002". 
      rotate y*45
      translate <Tx*16-48, Ty*15-37.5, 0>
      no_shadow
      }
  #declare Ty = Ty+1 #end
#declare Tx = Tx+1 #end