// QUALTIC2 - SPHERES by QUALTIC / A DREAM '02.06
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 12
  assumed_gamma 2.2
  }

/* Quartic */
// a00 x^4   +a01 x^3 y +a02 x^3z   +a03 x^3    + a04 x^2y^2 + 
// a05 x^2yz +a06 x^2 y +a07 x^2z^2 +a08 x^2z   + a09 x^2    + 
// a10 xy^3  +a11 xy^2z +a12 xy^2   +a13 xyz^2  + a14 xyz    + 
// a15 xy    +a16 xz^3  +a17 xz^2   +a18 xz     + a19 x      + 
// a20 y^4   +a21 y^3z  +a22 y^3    +a23 y^2z^2 + a24 y^2z   + 
// a25 y^2   +a26 yz^3  +a27 yz^2   +a28 yz     + a29 y      + 
// a30 z^4   +a31 z^3   +a32 z^2    +a33 z      + a34        = 0

// x^2+A^2*(y+B*(x^2+z^2))^2+z^2-1=C
#declare A=10; #declare B=1; #declare C=0;

quartic {
  <A*A*B*B,  0.0,  0.0,  0.0,  0.0,
       0.0,2*A*A*B,2*A*A*B*B,  0.0,  1.0,
       0.0,  0.0,  0.0,  0.0,  0.0,
       0.0,  0.0,  0.0,  0.0,  0.0,
       A*A,  0.0,  0.0,  0.0,  0.0,
       0.0,  0.0,2*A*A*B,0.0,  0.0,
   A*A*B*B,  0.0,  1.0,  0.0,-C-1.0 >  
  rotate <30, 0, 0>
  texture {
    pigment { color rgbt <1, 0.8, 0.7, 0.6> }
    finish {
      reflection 0.5
      phong 0.5
      phong_size 20
      ambient 0.2
      diffuse 0.8
      }
    }
  no_shadow
  }

camera {
  location <0, -0.5, -19.5>
  angle 7
  look_at <0.0, -0.5, 0.0>
  }

light_source { <200, 30, -300> colour rgb <1, 1, 1> }
light_source { <0, 0, 0> colour rgb <0.5, 0, 0> }
light_source { <0, -1, 0> colour rgb <0, 0.5, 0.5> }