// PLASMA / The Prominence '99.07
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 18
  assumed_gamma 2.2
  }

light_source {<0, 0, 2.6> color <1,0,0>}
light_source {<0, 0, -2> color <1,1,1>}

camera {
  location <0,0,-40>
  angle 2.4
  look_at <0.02, -0.03, 0>
  }

box {
  <-100, -100, 5> < 100,  100,  6>
  pigment {color rgb <0,0,0>}
  finish {ambient 0 diffuse 0.8 reflection 0 phong 2.8}
  normal {radial sine_wave frequency 1 turbulence 0.06 rotate x*90 rotate z*100}
  }

#declare I = 0; #while ( I < 4)

  sphere {
    <0, 0, 0> 0.5+0.0001*I
    #switch (I)
    #case (0)   //Yellow light sprere
      pigment {color rgbt <1,0.6,0,0.5>}
      finish {ambient 1.8 diffuse 0 reflection 0}
    #break
    #case (1)   //Big light zone
      pigment {
        marble color_map {
          [0.05 color rgbt <1, 0.9, 0.9, 1>]
          [0.5 color rgb <1, 0.5, 0>]
          }
        turbulence 2.8 scale 0.05 rotate y*145 rotate x*10 translate y*50
        scale 8
        }
      finish {ambient 0.2diffuse 0.8reflection 0}
    #break
    #case (2)   //Big dark zone
      pigment {
        marble color_map {
          [0.05 color rgbt <1, 0.9, 0.9, 0.8>]
          [0.5 color rgb <1, 0.5, 0>]
          }
        turbulence 0.8 scale 0.05 rotate y*140 translate y*50
        scale 8
        }
      finish {ambient 0.5 diffuse 0.8 reflection 0}
    #break
    #else      //Small pattern
      pigment {
        marble color_map {
          [0.1 color rgbt <0, 0, 0.3, 1>]
          [2 color rgb <0.6, 0, 0>]
          }
        turbulence 3.5 scale 0.015 rotate y*90 translate y*30
        scale 3
        }
      finish {ambient 0.5 diffuse 0.8 reflection 0}
    #end
    }
  #declare I = I+1; #end
 
//Prominence 
#declare Se = 8;
#declare R1 = seed(Se);
#declare Cn = 6; #while ( Cn < 26)
  #declare Sr = 0.22+0.0021*rand(R1);
  #declare Xs = 720*rand(R1)+200;
  #declare Ys = 720*rand(R1)-160;
  #declare Zs = 720*rand(R1);
  #declare Tbr = rand(R1);
  #declare Cm = 0; #while ( Cm < 2)
    sphere {
      <0, 0.30, 0> Sr-0.0001*Cm scale <0.6,1.2,1.2>
      pigment {
        marble color_map {
          [0.80+0.10*rand(R1) color rgbt <1, 0, 0, 1>]
          [1 color rgb <1, 0.6, 0>]
          }
        turbulence ((0.2+0.2*rand(R1))*(3-Cm))
        scale 0.03 translate y*50
        scale 3
        }
      finish {ambient 1.0 diffuse 0.8 reflection 0}
      rotate x*Xs rotate y*Ys rotate z*Zs
      no_shadow
      }
    #declare Cm = Cm+1; #end
  #declare Cn = Cn+1; #end