// POLAR / Sweets '00.02
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  max_trace_level 7
  assumed_gamma 2.2
  }

light_source {<20000, 100000, -50000> color <1,1,1>}
light_source {<-60000, -30000, -40000> color <1,1,1>}

camera {
  location <0,0,-10000>
  angle 6
  look_at <0, 0, 0>
  }

#declare Rdg=100;  //basic radius of sphere

//initialize the coordinates
#declare Vmax=72;
#declare Hmax=2*Vmax;
#declare Cp=array[Hmax][Vmax+2][4]
#declare V=0; #while (V<Vmax+1)
#declare H=0; #while (H<Hmax)
#declare I=0; #while (I<4)
  #declare Cp[H][V][I]=0;
#declare I=I+1; #end
#declare H=H+1; #end
#declare V=V+1; #end

//triangle of the surface
#macro Trid (Ph,Pv)
  #declare Ph1=mod(Ph-1+Hmax,Hmax);
  union {
    triangle {
      <Cp[Ph][Pv][0],Cp[Ph][Pv][1],Cp[Ph][Pv][2]>,
      <Cp[Ph1][Pv-1][0],Cp[Ph1][Pv-1][1],Cp[Ph1][Pv-1][2]>,
      <Cp[Ph][Pv-1][0],Cp[Ph][Pv-1][1],Cp[Ph][Pv-1][2]>
      }
    triangle {
      <Cp[Ph1][Pv][0],Cp[Ph1][Pv][1],Cp[Ph1][Pv][2]>,
      <Cp[Ph1][Pv-1][0],Cp[Ph1][Pv-1][1],Cp[Ph1][Pv-1][2]>,
      <Cp[Ph][Pv][0],Cp[Ph][Pv][1],Cp[Ph][Pv][2]>
      }
    texture {
      pigment { color rgb <Cp[Ph][Pv][3]/Rdg-0.6,0.8-J/3+I/8,I/2>}
      finish { ambient 0.25 }
      }
    }
#end

#declare J=0; #while (J<3)
  #declare I=0; #while (I<2)

    #declare V=0; #while (V<Vmax+2)
      #declare H=0; #while (H<Hmax)
        #if (V=0) #declare Vvmax=0; #else #declare Vvmax=0.999998*(V-1)/Vmax+0.000001; #end
        #if (I=0)
          #declare Hsphe=3+3*J;
          #declare Vsphe=1+2*J;
            #declare Cp[H][V][3]=0.000001+Rdg*(1+(1+cos(Vsphe*2*pi*Vvmax+pi)) *(1+sin(Hsphe*2*pi*H/Hmax-pi/3))*sin(pi*Vvmax)/4);
        #else
          #if (J=1)
            #declare Cp[H][V][3]=0.000001+2*Rdg*(pow(sin(2*pi*Vvmax-pi/4+pi/2-acos(1/sqrt(3))),8/(J+2)) *pow(abs(sin(2*pi-2*pi*H/Hmax+pi/4)),8/(J+2)) +pow(sin(2*pi-2*pi*Vvmax+pi/4-pi/2+acos(1/sqrt(3))),8/(J+2))*pow(abs(sin(2*pi*H/Hmax+pi/4)),8/(J+2)));
          #else
            #declare Cp[H][V][3]=0.000001+2*Rdg*pow(sin((J+2)/2*pi*Vvmax),8/(J+2)) *pow(sin((J+2)/2*2*pi*H/Hmax),8/(J+2));
          #end
        #end
        #declare Cp[H][V][0]=Cp[H][V][3]*sin(pi*Vvmax)*cos(2*pi*H/Hmax);
        #declare Cp[H][V][1]=Cp[H][V][3]*sin(pi*Vvmax)*sin(2*pi*H/Hmax);
        #declare Cp[H][V][2]=-Cp[H][V][3]*cos(pi*Vvmax);
      #declare H=H+1; #end
    #declare V=V+1; #end

    union {
      #declare V=2; #while (V<Vmax+2)
        #declare H=0; #while (H<Hmax)
          Trid (H,V)
        #declare H=H+1; #end
      #declare V=V+1; #end
      rotate <350-50*I,120,20-30*I>
      translate <-360+340*J,-180+360*I,0>
      no_shadow
      }

  #declare I=I+1; #end
#declare J=J+1; #end

background {color rgbt <0,0,0.2>}