// NET / Twin Hills Face of Hexagon Net '00.11
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  assumed_gamma 2.2
  }

light_source {<0, 0, -10> color <1,1,1>}

camera {
  location <0,-20,-15>
  angle 2.33
  look_at <0, 0, 0>
  }

#declare R1 = seed(5);
#declare Cos30 = cos(pi/6);

#macro Meshsquare(Pmaxx,Pmaxy,Rrand,Rsize)
  //initialize the coordinates
  #declare Cp=array[Pmaxx][Pmaxy][3]

  #declare Xp=0; #while (Xp<Pmaxx)
    #declare Yp=0; #while (Yp<Pmaxy)
      #declare Cp[Xp][Yp][0]=(Cos30*Xp-Rrand/2+Rrand*rand(R1))/Pmaxx/Cos30-0.5;
      #declare Cp[Xp][Yp][1]=(1.5*Yp-0.5*mod(Yp,2)-pow(-1,Yp)*0.5*mod(Xp,2)-Rrand/2+Rrand*rand(R1))/Pmaxx/Cos30-0.75*(Pmaxy-0.75)/Pmaxx/Cos30;
      #declare Cp[Xp][Yp][2]=-(1-cos(4*pi*Xp/Pmaxx))*(1-cos(2*pi*Yp/Pmaxy))/15;
    #declare Yp=Yp+1; #end
  #declare Xp=Xp+1; #end

  union {
  #declare Xp=0; #while (Xp<Pmaxx)
    #declare Yp=0; #while (Yp<Pmaxy)
      sphere { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> Rsize/Pmaxx }
      #if (Yp>0) #if (mod(Xp+Yp,2)=1) cylinder { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> <Cp[Xp][Yp-1][0],Cp[Xp][Yp-1][1],Cp[Xp][Yp-1][2]> Rsize/Pmaxx } #end #end
      #if (Xp>0) cylinder { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> <Cp[Xp-1][Yp][0],Cp[Xp-1][Yp][1],Cp[Xp-1][Yp][2]> Rsize/Pmaxx } #end
    #declare Yp=Yp+1; #end
  #declare Xp=Xp+1; #end
    pigment {color rgb <1,1,1>}
    finish { ambient 0.6 }
    no_shadow
    translate <0.5/Pmaxx,0.5/Pmaxx,0>
    }

#end

Meshsquare(61,40,0.7,0.08)