// NET / Disordering Square Net '00.11
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1;
global_settings {
  assumed_gamma 2.2
  }

light_source {<0, 0, 10> color <1,0.5,1>}

camera {
  location <0,0,-10>
  angle 5.85
  look_at <0, 0, 0>
  }

#declare R1 = seed(7);

#macro Meshsquare(Pmaxx,Pmaxy,Rrand,Rsize)
  //initialize the coordinates
  #declare Cp=array[Pmaxx][Pmaxy][3]

  #declare Xp=0; #while (Xp<Pmaxx)
    #declare Yp=0; #while (Yp<Pmaxy)
    #declare Modif=pow(pow(Xp-Pmaxx/2,2)+pow(Yp-Pmaxy/2,2),0.3)/pow(pow(Pmaxx/2,2)+pow(Pmaxy/2,2),0.3);
      #declare Cp[Xp][Yp][0]=(Xp-Modif*Rrand/2+Modif*Rrand*rand(R1))/Pmaxx-0.5;
      #declare Cp[Xp][Yp][1]=(Yp-Modif*Rrand/2+Modif*Rrand*rand(R1))/Pmaxx-0.5*Pmaxy/Pmaxx;
      #declare Cp[Xp][Yp][2]=0;
    #declare Yp=Yp+1; #end
  #declare Xp=Xp+1; #end

  union {
  #declare Xp=0; #while (Xp<Pmaxx)
    #declare Yp=0; #while (Yp<Pmaxy)
      sphere { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> Rsize/Pmaxx }
      #if (Yp>0) cylinder { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> <Cp[Xp][Yp-1][0],Cp[Xp][Yp-1][1],Cp[Xp][Yp-1][2]> Rsize/Pmaxx } #end
      #if (Xp>0) cylinder { <Cp[Xp][Yp][0],Cp[Xp][Yp][1],Cp[Xp][Yp][2]> <Cp[Xp-1][Yp][0],Cp[Xp-1][Yp][1],Cp[Xp-1][Yp][2]> Rsize/Pmaxx } #end
    #declare Yp=Yp+1; #end
  #declare Xp=Xp+1; #end
    pigment {color rgbt <1,0,0,0.8>}
    finish {
      reflection 1
      phong 1
      brilliance 2
      ambient 0.4
      }
    no_shadow
    translate <0.5/Pmaxx,0.5/Pmaxx,0>
    }

#end

Meshsquare(20,15,0.8,0.1)