// JULIA / LIGHT '99.01
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.1
global_settings { assumed_gamma 2.2 }

camera {
    location <-1.8, -1.0, -4.0>
    angle 100
    look_at <0.0, 0.0, 0.00>
}

light_source { <-20.00, 30.00, -100.00> color rgb <0.4,0.4,0.7> }
light_source { <200.00, 300.00, -500.00> color rgb <1,0.8,0.6> }
                        
#declare PREC = 1000;

#declare Px =-10; #while (Px < 11)
#declare Py =-10; #while (Py < 11)
#declare Pz =-3; #while (Pz < 20)
  julia_fractal {
    <0.03+Px/4,0.15+Px/6,-0.13+Py/4,0.25+Pz/4>
    quaternion
    cube
    max_iteration 10
    precision PREC
    texture { pigment {color rgb <1,0.8,0.4> } finish {reflection 0.3 ambient 0.2}}
    rotate <0,0,90> scale 0.3
    no_shadow 
    translate <Py, Px,  Pz> 
    }
  #declare Pz =Pz +1;  #end
  #declare Py =Py +1;  #end
  #declare Px =Px +1;  #end
        
sky_sphere {
    pigment {
      gradient y
      color_map {
        [ 0.2 color rgb <0.3,0.5,0.8> ]
        [ 1.00 color rgb <0,0,0> ]
        }
      scale 1.5
      }
    }