// Tree '98.06
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.0
global_settings { assumed_gamma 2.2 }

#include "colors.inc"

light_source {<50, 100, 50> color White}
light_source {<20, 30, 18> color White}

#declare Ct =3  #while (Ct > 0)
  #declare Cro =50-10*Ct                        //angle of branches
  #declare Cdo =7                               //ratio of increasing diameter
  #declare Cno =3                               //number of branches
  #declare Cbo =6                               //number of division
  #declare Objeb = cone {0.3*y, 0.0, 0*y, 0.02} //top shape of branch
  #declare R1 = seed(Ct)
  #declare Cb =Cbo  #while (Cb > 0)
    #declare Ratio = 0.7 +0.2*rand(R1)
    #declare Objeb = merge {
             merge { Objeb scale Ratio translate Ratio*y }
             cone { Ratio*y, Ratio*pow(Cno,0.25)*0.02*(1+(1+Cdo)*Cbo)/(Cdo*pow(Cno,0.5)+Cbo+Cdo*Cb), 0*y, 0.02*(1+(1+Cdo)*Cbo)/(Cbo+Cdo*Cb) }
             }
    #if (Cb > 1)
      #declare Yr =0
      #declare Obje = merge { Objeb rotate <Cro*(0.6+0.8*rand(R1)),Yr> }
      #declare Cn =Cno #while (Cn > 1)
        #declare Yr = Yr + (0.7+0.6*rand(R1))*360/Cno
        #declare Obje = merge {
             merge { Objeb rotate <Cro*(0.6+0.8*rand(R1)),Yr>}
             merge { Obje }
             }
      #declare Cn =Cn-1 #end
      #declare Objeb =merge { Obje }
    #else
        merge { Objeb
        texture { pigment { color rgb <1, 1, 1>} }
          #switch (Ct)
            #case (3) rotate y*20 translate <1.5,-0.1,0> #break
            #case (2) translate <-9.5,-0.2,-8> #break
            #else     translate <-12,0,-15>
          #end
          }
    #end
  #declare Cb = Cb-1 #end
#declare Ct = Ct-1 #end

camera {
    location <10,0.5,15>//<20, 40, -40>
    angle 14
    look_at <0, 1.8, 0>
    }

sky_sphere {
    pigment {
      gradient y
      color_map {
        [ 0.5  color Blue ]
        [ 1.0  color White ]
        }
      scale 2
      translate -1
      }
    }

#declare Orig_Fog = 1
#declare Ground_Mist= 2
fog{
    fog_type Ground_Mist
    fog_alt 0.3
    fog_offset 0
    distance 8
    color White
    turbulence <0.05, 0.05, 0.05>
    omega 0.25
    lambda 2.5
    octaves 6
    }