// Medusa '98.06
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.0
global_settings { assumed_gamma 2.2 }

#include "colors.inc"

camera {
    location <100,0,-100>
    angle 20
    look_at <0, 0, 0>
    }

light_source {<50, 100, 50> color White}
light_source {<20, 30, 18> color White}

#declare Cn =1 #while (Cn < 14)
  #declare R1 = seed(Cn*4)
  #declare Xr = 360*rand(R1)
  #declare Yr = 360*rand(R1)
  #declare Xp =0
  #declare Yp =0
  #declare Zp =0
  #declare Cend =70
  #declare Ct =0 #while (Ct < Cend+1)
    #declare Xr =Xr+15*rand(R1)
    #declare Yr =Yr+15*rand(R1)
    #if (Ct=Cend)
      sphere { <0, 0.5, 0> 1.5 scale <0.5,1,0.5> rotate <Xr,Yr,0> translate <Xp,Yp,Zp>
        pigment {color rgb <1-Cn/14, 0, Cn/14-1>}
        finish {
            ambient 0.3
            crand 0.1
            reflection 0.2
            specular 1.0
            brilliance 1.0
        }
        }
    #else
      sphere { <0, 0.5, 0> 2 scale (Cend-Ct/1.2)/Cend rotate <Xr,Yr,0> translate <Xp,Yp,Zp>
        pigment {color rgb <1-Cn/14, 0, Cn/14-1>}
        finish {
            ambient 0.3
            crand 0.1
            reflection 0.2
            specular 1.0
            brilliance 1.0
            }
        }
    #end
    #declare Xp =Xp+sin(Xr*pi/180)*sin(Yr*pi/180)*(1.5*Cend-Ct)/1.5/Cend
    #declare Yp =Yp+cos(Xr*pi/180)*(1.5*Cend-Ct)/1.5/Cend
    #declare Zp =Zp+sin(Xr*pi/180)*cos(Yr*pi/180)*(1.5*Cend-Ct)/1.5/Cend
  #declare Ct = Ct+1 #end
#declare Cn = Cn+1 #end

sky_sphere {
    pigment {
      gradient y
      color_map {
        [ 0.5  color Red ]
        [ 1.0  color White ]
        }
      scale 2
      translate -1
      }
    }