CC」や「BCC」を追加してみます。

CC」や「BCC」の他、添付ファイルの記述もコメントで入れました。
Excel同様の「メール送信」のお題です。  Visual Basic.NET(2005以降)」の利用者(開発者)は「メール送信」などで悩むようなことは少ないと思います。 現在では、Web上でこのような情報はいくらでも見つかりますから。 ですが、ExcelVBAから移行してくるような「VB初心者」もたくさんいるだろうと思うので、念のためサンプルを挙げておきます。
プロジェクトのサンプルはダウンロードできますが、今回は「Visual Basic 2008 Express Edition」で作成しています。

前ページと同様に必要項目を入力して、「送信」ボタンで送信されます。
簡単なフォームを用意
(画像をクリックすると、プロジェクトフォルダの圧縮ファイルがダウンロードできます。)
こんなフォームを用意してあり「送信」ボタンで送信されるようにしてあります。
今回のサンプルから、複数宛先、複数CC、複数BCCに対応するようにしてあります。 複数件を登録する場合は、「カンマ」で区切って入力して下さい。

実際に送信されると、
送信成功のメッセージ
このようにメッセージが表示されます。

送信が失敗した場合は、
送信失敗のメッセージ
このようにエラーメッセージが表示されます。
この画像のメッセージは、SMTPサーバが見つからない状態のものですが、SMTPサーバから返されるメッセージについてはもう少し詳細なものになると思います。

では、このサンプルのソースコードを紹介します。

'*******************************************************************************
'   メール送信のテスト2(CC,BCCの付加)
'
'   作成者:井上治  URL:https://www.ne.jp/asahi/excel/inoue/ [Excelでお仕事!]
'*******************************************************************************
Imports System.Net
Public Class frmSendMailTEST2
    Private Const g_cnsTitle As String = "メール送信のテスト"
    Private Const g_cnsComm As String = ","
    '---------------------------------------------------------------------------
    ' ↓SMTPサーバのIPアドレスかSMTPサーバ名を記述して下さい。
    Private Const g_cnsSMTP As String = "xxx.xxx.xxx.xxx"
    ' メール送信環境
    Private Const g_cnsMailPort As Integer = 25             ' ポート№
    Private Const g_cnsTimeout As Integer = 60000           ' タイムアウト
    Private Const g_cnsMailSSL As Boolean = False           ' SSL使用有無
    Private Const g_cnsSMTPAuth As Boolean = False          ' SMTP認証使用有無
    Private Const g_cnsSMTPAuthID As String = "hoge"        ' SMTP認証ユーザーID
    Private Const g_cnsSMTPAuthPW As String = "password"    ' SMTP認証パスワード

    '***************************************************************************
    '   「送信」ボタンのクリック
    '***************************************************************************
    Private Sub BTN_SEND_Click(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles BTN_SEND.Click
        '-----------------------------------------------------------------------
        ' 発信元
        Dim strFrom As String = TXT_FROM.Text.Trim
        ' 宛先(複数の場合はカンマで区切る)
        Dim strTo As String = TXT_TO.Text.Trim
        ' CC(複数の場合はカンマで区切る)
        Dim strCc As String = TXT_CC.Text.Trim
        ' BCC(複数の場合はカンマで区切る)
        Dim strBcc As String = TXT_BCC.Text.Trim
        ' 件名
        Dim strSubj As String = TXT_SUBJ.Text.Trim
        ' 本文
        Dim strBody As String = TXT_BODY.Text.Trim
        '-----------------------------------------------------------------------
        ' 入力内容のチェック
        If strFrom = "" Then
            MessageBox.Show("「発信元」が入力されていません。", _
                g_cnsTitle, MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
            Exit Sub
        ElseIf strTo = "" Then
            MessageBox.Show("「宛先」が入力されていません。", _
                g_cnsTitle, MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
            Exit Sub
        ElseIf strSubj = "" Then
            MessageBox.Show("「件名」が入力されていません。", _
                g_cnsTitle, MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
            Exit Sub
        ElseIf strBody = "" Then
            MessageBox.Show("「本文」が入力されていません。", _
                g_cnsTitle, MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
            Exit Sub
        End If
        '-----------------------------------------------------------------------
        ' Mailmessageの作成
        Dim objMessage As New Mail.MailMessage()
        With objMessage
            ' 発信元
            .From = New Mail.MailAddress(strFrom)
            ' 宛先
            Dim tblAddr() As String, IX As Integer = 0
            tblAddr = strTo.Split(g_cnsComm)
            Do While IX < tblAddr.Length
                .To.Add(New Mail.MailAddress(tblAddr(IX).ToString))
                IX += 1
            Loop
            ' CC
            If strCc <> "" Then
                tblAddr = strCc.Split(g_cnsComm)
                IX = 0
                Do While IX < tblAddr.Length
                    .CC.Add(New Mail.MailAddress(tblAddr(IX).ToString))
                    IX += 1
                Loop
            End If
            ' BCC
            If strBcc <> "" Then
                tblAddr = strBcc.Split(g_cnsComm)
                IX = 0
                Do While IX < tblAddr.Length
                    .Bcc.Add(New Mail.MailAddress(tblAddr(IX).ToString))
                    IX += 1
                Loop
            End If
            ' ファイルを添付する場合は下記のような記述を追加します。
            '.Attachments.Add(New Mail.Attachment("C:\HOGE.xls"))
        End With
        '-----------------------------------------------------------------------
        ' SMTPクライアントの取得
        Dim objSMTPClient As New Mail.SmtpClient()
        ' メール送信の環境設定(一般の非認証サーバではHostの指定のみで良い)
        With objSMTPClient
            ' SMTPサーバの指定
            .Host = g_cnsSMTP
            ' ポート№
            .Port = g_cnsMailPort
            ' SSL使用
            .EnableSsl = g_cnsMailSSL
            ' SMTP認証(※この記述は現在環境により動作未確認です)
            If g_cnsSMTPAuth Then
                .Credentials = New NetworkCredential( _
                    g_cnsSMTPAuthID, g_cnsSMTPAuthPW)
                '.UseDefaultCredentials = True
            End If
            .Timeout = g_cnsTimeout
        End With
        '-----------------------------------------------------------------------
        ' メールの送信
        BTN_SEND.Enabled = False
        Try
            objSMTPClient.Send(objMessage)
            ' 完了メッセージ
            MessageBox.Show("メールを送信しました。", g_cnsTitle, _
                MessageBoxButtons.OK, MessageBoxIcon.Information)
            ' 発信元以外をクリア
            TXT_TO.Text = ""
            TXT_CC.Text = ""
            TXT_BCC.Text = ""
            TXT_SUBJ.Text = ""
            TXT_BODY.Text = ""
        Catch ex As Exception
            ' エラー表示
            MessageBox.Show("メール送信に失敗しました。" & vbCr & ex.Message, _
                g_cnsTitle, MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
        BTN_SEND.Enabled = True
    End Sub

    '-----------------------------<< End of Source >>---------------------------
End Class

※このサンプルはいきなり動作させてもメール送信は実現しません。

    ' ↓SMTPサーバのIPアドレスかSMTPサーバ名を記述して下さい。
    Private Const g_cnsSMTP As String = "xxx.xxx.xxx.xxx"
必ずこのSMTPサーバの設定を実行環境に合わせて変更してから動作確認して下さい。
※「送信時認証」に関する記述も埋め込んでいます。

        ' メール送信の環境設定(一般の非認証サーバではHostの指定のみで良い)
        With objSMTPClient
            ' SMTPサーバの指定
            .Host = g_cnsSMTP
            ' ポート№
            .Port = g_cnsMailPort
            ' SSL使用
            .EnableSsl = g_cnsMailSSL
            ' SMTP認証(※この記述は現在環境により動作未確認です)
            If g_cnsSMTPAuth Then
                .Credentials = New NetworkCredential( _
                    g_cnsSMTPAuthID, g_cnsSMTPAuthPW)
                '.UseDefaultCredentials = True
            End If
            .Timeout = g_cnsTimeout
        End With
ですが、これは「可能性がある記述」とご理解下さい。
元々、インターネットメールは通常の「郵便」と同じセキュリティレベルなので、メールの送信には一切認証行為はありません。 これは誰でも「郵便」をポストに投函できるのと同じであって、「なりすまし」「架空差出人」は自由にできるものだったのです。 ですが、これを利用したSPAMメールがあまりにも蔓延してしまったため、企業やプロバイダ等は「送信時認証」を採用する動きになってきています。
しかし、導入される「送信時認証」にはあまりにも種類・レベルが多く、このようなプログラムからの送信が全てに対応できるものではありません。 とりあえず、「それらしい」プロパティに値をセットできるように記述してみてありますが、当方の環境では動作検証ができていないので、各環境で試行錯誤していただくしかないのが現状です。
従来通りの「送信時認証」が採用されていないSMTPサーバでの記述については、上記を

        ' SMTPサーバの指定
        objSMTPClient.Host = g_cnsSMTP
だけにしてしまっても動作するはずです。

今回は、添付ファイルについての画面入力等を対応していませんが、

        ' ファイルを添付する場合は下記のような記述を追加します。
        'objMessage.Attachments.Add(New Mail.Attachment("C:\HOGE.xls"))
コメントにしてあるこのような記述を追加することで添付ファイルも実現できます。