デフォルトは、Application.EnableCancelKey = xlInterruptです。
無限ループをわざと作成して見ます。
'***************************************************************************************************
' Escキー動作テスト Module1(Module)
'
' 作成者:井上治 URL:https://www.ne.jp/asahi/excel/inoue/ [Excelでお仕事!]
'***************************************************************************************************
'変更日付 Rev 変更履歴内容------------------------------------------------------------------------>
'03/07/30(1.00)新規作成
'12/01/22(1.01)初回修正
'20/02/23(1.10)*.xlsm化、他
'***************************************************************************************************
Option Explicit
'***************************************************************************************************
' ■■■ ワークシート側からの呼び出し処理 ■■■
'***************************************************************************************************
'* 処理名 :EscKeyTEST1
'* 機能 :Escキー動作テスト①
'---------------------------------------------------------------------------------------------------
'* 返り値 :(なし)
'* 引数 :(なし)
'---------------------------------------------------------------------------------------------------
'* 作成日 :2003年07月30日
'* 作成者 :井上 治
'* 更新日 :2020年02月23日
'* 更新者 :井上 治
'* 機能説明:何もエラー制御を行なわない場合
'* 注意事項:
'***************************************************************************************************
Sub EscKeyTEST1()
'-----------------------------------------------------------------------------------------------
' 無限ループを生成する
Do
' ループ中では何もしない
Loop
End Sub
'***************************************************************************************************
'* 処理名 :EscKeyTEST2
'* 機能 :Escキー動作テスト②
'---------------------------------------------------------------------------------------------------
'* 返り値 :(なし)
'* 引数 :(なし)
'---------------------------------------------------------------------------------------------------
'* 作成日 :2003年07月30日
'* 作成者 :井上 治
'* 更新日 :2020年02月23日
'* 更新者 :井上 治
'* 機能説明:Escキーを無効にする("100-10-100"まで止まらない)
'* 注意事項:
'***************************************************************************************************
Sub EscKeyTEST2()
'-----------------------------------------------------------------------------------------------
Dim lngIx1 As Long ' テーブルINDEX①
Dim lngIx2 As Long ' テーブルINDEX②
Dim lngIx3 As Long ' テーブルINDEX③
' ESCキーを無効にする
Application.EnableCancelKey = xlDisabled
' 外ループ処理
For lngIx1 = 1 To 100
' 中ループ処理
For lngIx2 = 1 To 10
' 内ループ処理
For lngIx3 = 1 To 100
' カウントを表示
Application.StatusBar = _
lngIx1 & "-" & lngIx2 & "-" & lngIx3
Next lngIx3
Next lngIx2
Next lngIx1
' セットしたプロパティを初期値に戻す
Application.EnableCancelKey = xlInterrupt
Application.StatusBar = False
End Sub
'***************************************************************************************************
'* 処理名 :EscKeyTEST3
'* 機能 :Escキー動作テスト③
'---------------------------------------------------------------------------------------------------
'* 返り値 :(なし)
'* 引数 :(なし)
'---------------------------------------------------------------------------------------------------
'* 作成日 :2003年07月30日
'* 作成者 :井上 治
'* 更新日 :2020年02月23日
'* 更新者 :井上 治
'* 機能説明:都合が良い所で中断処理を行なう
'* 注意事項:
'***************************************************************************************************
Sub EscKeyTEST3()
'-----------------------------------------------------------------------------------------------
Dim lngIx1 As Long ' テーブルINDEX①
Dim lngIx2 As Long ' テーブルINDEX②
Dim lngIx3 As Long ' テーブルINDEX③
Dim swEND As Boolean ' 終了判定スイッチ
' エラー処理を登録
On Error GoTo ERR1
' ESCキーでエラー処理に進む
Application.EnableCancelKey = xlErrorHandler
' 外ループ処理
For lngIx1 = 1 To 100
' 中ループ処理
For lngIx2 = 1 To 10
swEND = False
' 内ループ処理
For lngIx3 = 1 To 1000
' カウントを表示
Application.StatusBar = _
lngIx1 & "-" & lngIx2 & "-" & lngIx3
Next lngIx3
' 中断の判断(カウントは内ループ終了のタイミング゙)
If swEND Then
' 終了確認
If MsgBox("中断キーが押されました。" & vbCr & _
"終了しますか?", vbYesNo) = vbYes Then GoTo EXIT1
End If
Next lngIx2
Next lngIx1
' 終了処理に進む
GoTo EXIT1
'===================================================================================================
' エラー処理
ERR1:
' Escキー打鍵か
If ERR.Number = 18 Then
' Escキーでのエラートラップなのでスイッチをセットして戻る
swEND = True
Resume
Else
' 他の実行時エラーはメッセージを表示して終了
MsgBox ERR.Number & " " & ERR.Description, vbCritical
End If
'===================================================================================================
' 終了処理
EXIT1:
' セットしたプロパティを初期値に戻す
Application.EnableCancelKey = xlInterrupt
Application.StatusBar = False
End Sub